Datensicherung - Konfigurationsbeispiel

Fragen, Anregungen oder Tipps und Tricks? Hier ist der erste Anlaufpunkt.
Nicht sicher, wo ein Thema hingehört? Hier hinein - wir kümmern uns! :)

Moderator: Forum Moderatoren

Forumsregeln
TM-Startforum - "offen für alle Themen".
Beiträge, die in einen anderen Bereich passen, werden bei Bedarf verschoben.
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo,

vor kurzer Zeit habe ich das Datensicherungskonzept in meiner Praxis überarbeitet. Es funktioniert zu meiner großen Zuriedenheit. Deshalb möchte ich es dieser Community nicht vorenthalten.

In unserer Gemeinschaftspraxis sind 6 Rechner in Betrieb. Es ist ein Peer-to-Peer Netzwerk unter Windows XP (Anmerkung 1). Der Server hat den Namen "Bach", der 'Ersatzserver' hat den Namen "Chopin" (nur zum Verständnis für die unten angeführte Batch-Datei). Alle TurboMed Daten befinden sich bei allen Rechnern der Praxis auf dem Verzeichnis " C:\tmdaten ".

Diese Daten werden zweimal am Tag (11:00 Uhr und 18:00 Uhr) per Windows-eigenen Taskmanager via der hier geposteten Batch-Datei von Bach zu Chopin in das Verzeichnis C:\tmdaten von Chopin kopiert. Dabei ist das Laufwerk C:\tmdaten von Bach auf das Laufwerk Z:\ gemappt und das Verzeichnis C:\TurboMed von Bach auf das Laufwerk T:\ . Dadurch sind auf Chopin immer relativ aktuelle Datensätze vorhanden.

Auch die eigescannten Dokumente (nur) von 2010 werden ebenfalls noch gesichert in eine 7-Zip Datei. Da wir ca. 450.000 gescannte Dokumente haben, beschränken wir uns auf das Jahr 2010, da alle anderen Dokumente schon mehrmals separat gesichert worden sind.

Anschließend werden diese Daten dann auf dem Rechner Chopin noch umkopiert und zwar in das Verzeichnis c:\tmdaten_sich_wochenweise . Jeder Wochentag hat die Unterverzeichnisse 01 bis 05 und die Daten 'schieben' sich mit jeder Sicherung von 01 bis 05, so dass stets alle Daten der letzten zwei Wochen vorhanden sind.

Beim Ausfall des Servers (ist zum Glück noch nie passiert!) wird nun Chopin mittels der ebenfalls hier geposteten Batch Datei zum Server und allen anderen Rechnern noch mittels Batch-Datei mitgeteilt, dass nun "Chopin" der "Chef" – sprich Server - ist. Das ist eine Aktion von höchstens zwei Minuten und die Praxis "läuft" wieder.

Wenn Sie Lust haben, schauen Sie sich die unten angeführten Batch-Dateien an. Ich habe sie noch mit einigen Bemerkungen ergänzt.

Weitere Fragen jederzeit gerne!

A. Geigenberger

Anmerkung 1:
Ja das geht durchaus! Obwohl unser "Server" an der Anmeldung steht und auch alle Faxe empfängt und über ihn alle Daten eingescannt werden und er auch noch als 'Arbeitsplatzrechner' täglich seine treuen Dienste verrichtet, kam es noch nie zu einem 'Absturz'. Chipkarten werden über diesen Rechner allerdings nicht eingelesen, da dies doch ganz selten 'mal zu Abstürzen führt. Und wenn ich Ihnen nun noch sage, dass dieser Rechner mit einem alten Athlon auf Sockel A Basis arbeitet, dann werden einige Leser wahrscheinlich den Kopf schütteln. Aber der Poet-Server braucht sehr wenig Resourcen und der Flaschenhals in TurboMed Netzwerken ist die Festplatte – und da habe ich eine sehr schnelle Western Digital Raptor Platte. Der allerschnellste Rechner nützt nämlich nichts, wenn die Festplatte die Daten nicht schnell genug liefert, da dieser Rechner dann ständig auf die Festplatte "wartet". Also seien Sie kritisch! Hier im Forum sind einige EDV-Händler unterwegs, die Ihnen natürlich nur die schnellsten und teuersten Rechner verkaufen wollen.


<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
<<<< Datensicherung.bat <<<<<<<<<<<<<<<<<<<

@echo off
@cls
@echo off

rem #### Hier wird der Wochentag 'ausgerechnet'.

FOR /F "tokens=1,2,3 delims=." %%a in ('echo %date%') do set yy=%%c & set mm=%%b & set dd=%%a

set /a "TwoDigitYearMax=2038%%1000"
if 1%yy% LSS 200 if 1%yy% LSS 1%TwoDigitYearMax% (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1

If %dow% equ 1 set "WoTa=Montag"
If %dow% equ 2 set "WoTa=Dienstag"
If %dow% equ 3 set "WoTa=Mittwoch"
If %dow% equ 4 set "WoTa=Donnerstag"
If %dow% equ 5 set "WoTa=Freitag"
If %dow% equ 6 set "WoTa=Samstag"
If %dow% equ 7 set "WoTa=Sonntag"

echo.
echo.
echo.
echo.
echo.
echo ########## Sicherung wichtiger Praxis-Daten #########
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo.
ping -n 1 x 127.0.0.1 > NUL
ping -n 1 x 127.0.0.1 > NUL

rem ### Der Server wird in den Backup-zustand versetzt. Weiterarbeiten in der Praxis ist möglich!!

T:\Programm\TMAdmin /beginBackup /server=Bach

cls
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo ############ Spiegelung der Praxis-Datenbank
echo.
xcopy Z:\Dictionary C:\tmdaten\Dictionary\ /s /e /c /h /y /d
xcopy Z:\DruckDB C:\tmdaten\DruckDB\ /s /e /c /h /y /d
xcopy Z:\PraxisDB C:\tmdaten\PraxisDB\ /s /e /c /h /y /d

T:\Programm\TMAdmin /endbackup /server=Bach

xcopy Z:\Symbole C:\tmdaten\Symbole\ /s /e /c /h /y /d
xcopy Z:\Vorlagen C:\tmdaten\Vorlagen\ /s /e /c /h /y /d
xcopy T:\Desktopobjekte C:\tmdaten\Desktopobjekte\ /s /e /c /h /y /d
echo.
rem Dateien werden an zwei Stellen des TM-Dateisystems gelegt (man weiss ja nie :-)
echo.
xcopy C:\tmdaten\Symbole C:\TurboMed\Symbole\ /s /e /c /h /y /d
xcopy C:\tmdaten\Vorlagen C:\Turbomed\Vorlagen\ /s /e /c /h /y /d
xcopy C:\tmdaten\Desktopobjekte C:\TurboMed\Desktopobjekte\ /s /e /c /h /y /d

rem StammDB braucht man nicht sichern (sh unten) xcopy Z:\StammDB C:\tmdaten\StammDB\ /s /e /c /h /y /d
rem Dokumente gelegentlich direkt kopieren gesicht wird das letzte Jahr mit 7z

rem #### Eine Datei wird eingefügt mit Info über den Zeitpunkt der Datensicherung

echo Erstellt am: %date% um: %time% > C:\tmdaten\B_%date:~-4%_%date:~-7,2%_%date:~-10,2%_%time:~-0,2%_%time:~3,2%_%time:~6,2%_%time:~9,2%.txt

cls
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo ############ Komprimieren der Dokumente von 2010
echo.

rem (Alle Dateien : zu viele!)
rem C:\Programme\7-Zip\7z u C:\tmdaten_Dokumente\PDFs.7z Z:\Dokumente\*
rem (Nur Dateien von 2010)

C:\Programme\7-Zip\7z u C:\tmdaten_Dokumente\PDF2010.7z Z:\Dokumente\Sonstiges\2010*
rem pause

cls
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo ############ ....umkopieren
echo.

Rmdir /Q /S C:\tmdaten_sich_wochenweise\%WoTa%\O5
ren C:\tmdaten_sich_wochenweise\%WoTa%\O4 O5
ren C:\tmdaten_sich_wochenweise\%WoTa%\O3 O4
ren C:\tmdaten_sich_wochenweise\%WoTa%\O2 O3
ren C:\tmdaten_sich_wochenweise\%WoTa%\O1 O2
Mkdir C:\tmdaten_sich_wochenweise\%WoTa%\O1

xcopy C:\tmdaten\Dictionary C:\tmdaten_sich_wochenweise\%WoTa%\O1\Dictionary\ /s /e /c /h /y /d
xcopy C:\tmdaten\DruckDB C:\tmdaten_sich_wochenweise\%WoTa%\O1\DruckDB\ /s /e /c /h /y /d
xcopy C:\tmdaten\PraxisDB C:\tmdaten_sich_wochenweise\%WoTa%\O1\PraxisDB\ /s /e /c /h /y /d
xcopy C:\tmdaten\Vorlagen C:\tmdaten_sich_wochenweise\%WoTa%\O1\Vorlagen\ /s /e /c /h /y /d

rem StammDB sollte bei jedem Update von TurboMed aktualisiert werden (noch kontrollieren!!)
rem von denDokumenten wird nur das aktuelle Jahr in die folgende 7-Zip Datei gesichert (gel manuelles Sichern aller Dokummente nötig)

xcopy C:\tmdaten_Dokumente\PDF2010.7z C:\tmdaten_sich_wochenweise\%WoTa%\O1\ /s /e /c /h /y /d

echo Erstellt am: %date% um: %time% > C:\tmdaten_sich_wochenweise\%WoTa%\O1\A_%date:~-4%_%date:~-7,2%_%date:~-10,2%_%time:~-0,2%_%time:~3,2%_%time:~6,2%_%time:~9,2%.txt

rem ####### ENDE ##########


<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
<<<< Abbruch Sicherung.bat <<<<<<<<<<<<<<<<<<<<<<<

rem #### noch nie gebraucht: Beendet den Datensicherungsmodus der Datenbank

@cls
@echo "Abbruch Sicherung"
T:\Programm\TMAdmin /endbackup /server=Bach


<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
<<<< Serverwechsel.bat <<<<<<<<<<<<<<<<<<<<


@ECHO OFF
:Anfang
cls
ECHO.
echo.
echo ##### Serverwechsel !!! ####
echo.
Echo.
set var2=xxxxxyyyy
set /p var11=Willst Du das wirklich??? (ja):

if NOT "%var11%" == "ja" goto Ende
cls
echo.
echo.
echo ##### Serverwechsel !!! ####
echo.
echo.
echo Server wird Bach : 1
echo.
echo Server wird Chopin : 2
echo.
echo Lieber kein Serverwechsel: (beliebige Eingabe)
echo.
echo.
set /p var11= Eingabe (1,2,beliebig) :

if "%var11%" == "1" goto Bach
if "%var11%" == "2" goto Chopin

goto Ende

:Bach
echo.
echo.
echo jetzt wird Bach der Server
echo.
echo.
xcopy C:\Ini_Dateien_Verdi\Server_ist_Bach\local.ini C:\TurboMed\Programm\ /P
pause
goto Ende

echo.
echo.
:Chopin
echo.
echo.
echo jetzt wird Chopin der Server
echo.
echo.
xcopy C:\Ini_Dateien_Verdi\Server_ist_Chopin\local.ini C:\TurboMed\Programm\ /P
pause
goto Ende


:Ende
SFeu
Beiträge: 337
Registriert: Donnerstag 28. Mai 2009, 18:48
14
Hat sich bedankt: 31 times
Bedankt: 19 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von SFeu »

Danke für den interessanten Bericht, wobei ich in meiner Praxis bezüglich der
Sicherung deutlich kleinere Brötchen backe. Jeden Abend spiegele ich Turbomed
auf meinen Hausrechner, den ich bei Bedarf als Server einsetzen kann.

Volle Zustimmung zum Problem Rechnerperformance - hier berichteten Kollegen (?)
über ihren hardwareseitigen Overkill mit Wahnsinns-Servern, mein Server leistet
sich mit 4 Terminals keine Hänger und hat doch nur einen alten Zweikernprozessor-
aber eine schnelle WD-Festplatte und 4GB Speicher.

Grüße,
SFeu
Benutzeravatar
wahnfried
PowerUser
Beiträge: 3180
Registriert: Freitag 13. Januar 2006, 23:46
18
Wohnort: Braunschweig

Re: DatenSPIEGELUNG - Konfigurationsbeispiel

Beitrag von wahnfried »

Hallo Herr Geigenberger,

Ihr sehr interessantes Konzept ist eines zur DATENSPIEGELUNG, nicht zur DatenSICHERUNG (sofern man unter "Sicherung" wie bei TurboMed intern versteht, daß diese auch überprüft ist).

nach dem ersten Durchlesen Ihrer "Werkzeuge" möchte ich an drei Dinge aus früheren Threads erinnern:

1) Es gab (auch bei mir) mit dem Schalter /d bei xcopy Schwierigkeiten, sofern auf die Datenbanken von TurboMed angewandt. Daher verwende ich für die Datenbanken diesen Schalter nicht. (Siehe meine Spiegelungs-Batch im WIKI unter "Datensicherung im Betrieb"). Für die Dokumente / KVDT / Formulare / Befunde gerne auch xcopy mit dem Schalter /d (= Neue oder neuere Dateien als am Spiegelort vorhanden).

2) Es wird allgemein abgeraten TurboMed auf der Systempartition zu installieren. Sollte ein Systemcrash erfolgen, der die Systempartition unbrauchbar macht, ist es meist möglich, auf weitere Partitionen zuzugreifen, wenn man die Festplatte in einen anderen PC als zweite Festplatte einbaut, nicht unbedingt (eher gar nicht?) aber auf Ordner der Systempartition. Das wäre der Unterschied zwischen den Praxisdaten zum Zeitpunkt der letzten Sicherungsroutine bis zum Zeitpunkt des Systemcrashes, der dann nach dem Serverwechsel verloren wäre, bei TurboMed auf "Nicht-C" aber rekonstruierbar wäre (egal, ob man die Daten seit dem Serverwechselauf der Platte des Ersatzservers per Hausbesuchsmodul der Datenbank auf der Crash-Server-Festplatte implementiert oder die Daten der gecrashten Platte seit der letzten Sicherung (deren Zeit Sie ja dokumentieren) auf der Platte des ERstzservers implementiert.

Diese Nacharbeit wäre danan ja am Abend nach dem Crash-Tag dran, um diese Lücke zu rekonstruieren. Kann ja auch sein, daß die Festplatte des Crash-Servers NICHT DEFEKT ist, sondern Mainboard/Grafikkarte/Hauptspeicher uws. (insofern auch über Einbau der Serverfestplatte in einen Wechsel-Einschub überlegen, um diese sehr rasch in einem zweiten Rechner testen zu können.

3) Es wurde oft darauf hingewiesen, daß mit "Robocopy" die Spiegelung schneller abläuft als mit "xcopy". Da mich die derzeitigen Spiegelungszeiten aber noch nicht stören, verwende ich Robocopy noch nicht.


Bemerkung zur Darstellung von Code im Forum:

In einer Batch-Datei können hinter "rem" oder "echo" viele Leerzeichen stehen, im Forum wird das leider immer auf eines reduziert, sofern der Code direkt im Text gepostet wird. Ein größerer Abstand eines informellen Kommentares zu der Zeilen-Einleitung "echo" oder "rem" bedeutet nach meiner Erfahrung: bessere Übersichtlichkeit. Auf der anderen Seite wird der Code - sofern hier als Code definiert - in einem recht kleinen Fenster mit Scrollbalken angezeigt, so daß die Übersicht über die Struktur des Codes schwieriger ist (außer man extrahiert ihn und man schaut ihn sich außerhalb des Forum an). Der Leser ist oben also darauf angewiesen, ggfs. die Übersichtlichkeit selbst wieder zu verbessern, falls der Postende nicht Punktreihen zur Abstandserzeugung verwendet.

Dafür werden hier Backslash-Zeichen korrekt dargestellt, im Hippokranet geht das z.B. nicht, da werden die immer in normale Schrägstriche umgewandelt.

Im Sinne dieser Übersichtlichkeit habe ich bei meinen Batch-Dateien noch Kommentare eingefügt, die den Betrachtern der während der Spiegelung am PC-Bildschirm erscheinenden DOS-Fenster ggfs mitteilen, das beim Kopieren der ersten Datenbank-Dateien Geduld erforderlich ist, weil wirklich mal eine Minute keinerlei Bewegung und Aktivität zu sehen ist (bis die nächste Datei dran kommt...) und daß nach dem Kopieren der Dateien einer Datenbank angegeben wird, wieviele Dateien da kopiert worden sein müssen, um das mit der darüberstehenden "erledigt"-Meldung von xcopy zu vergleichen. (Nicht daß jemand aufgrund scheinbarer Inaktivität das DOS-Fenster wegklickt...)

Bemerkung zum Thema "Kontrolle der ablaufenden Aktion":

Ich möchte auch am Ende einer Spiegelung sehen, daß die Datenbanken korrekt beendet wurde, deswegen habe ich den TMAdmin-endbackup-Befehl immer am Ende der Datenspiegelungsroutine vor dem Schlußbefehl "Pause" aufgeführt (die von mir im WIKI eingestellte downloadbare Batch-Datei macht dies aber nach meiner Erinnerung gleich nach dem Spiegeln der Datenbanken). Wenn die Sicherung der sonstigen Ordner(neue Dateien) aber recht lange dauert, kann es sehr sinnvoll sein, dies - wie in Ihrer Spiegelungs-Batch - bereits VOR dieser Aktion (und NACH dem Spiegeln der Datenbanken) durchzuführen, um den Zeitraum des Backupmodus nicht unnötig auszuweiten.
Es spräche aber auch nichts dagegen, sofern jemand diese Kontrolle will, den TMAdmin-endBackup-Befehl am Ende der Batch vor einem Pause-Befehl nochmal zu wiederholen. Bisher habe ich aber zum Prüfen der korrekten Beendigung des Backupmodus eine separate Batch laufen, die sowohl den TMAdmin-beginBackup- als auch den TMAdmin-endBackup-Befehl nacheinander aufführt (natürliche dann noch "pause"). Werde Ihre Version mit "NUR" Endbackup aber gleich testen...

Viele Grüsse, Wahnfried

p.s. zum Thema Server als Arbeitsplatz: Auch ich arbeite ohne jegliche Probleme auf dem TurboMed-Server als Arbeitsplatz, aber der steht in einem meiner beiden Behandlungszimmer, weil die MFA in der Anmeldung die Rechner deutlich stärker/intensiver benutzen als ich in meinem Arbeitszimmer (selbst wenn ich gerade dort behandle...). Ansonsten bin ich noch darauf gekommen, daß am Arbeitsplatz mit dem stationären KVK-Lesegerät nicht der Anmeldungsdrucker angeschlossen sein sollte, weil dann das Einlesen von KVK das gleichzeitige Drucken verlangsamt. Da aber in fast jeder Anmeldung zwei Arbeitsplätze stehen, kann man das dann gut entflechten. Das Einlesen von KVK-Daten des mobilen Lesegerätes dann gerne an dem druckenden Arbeitsplatz der Anmeldung, weil das eher in Zeiten geringeren Arbeitsanfalles stattfindet. W.
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: DatenSPIEGELUNG - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo Herr Wahnfried,
wahnfried hat geschrieben:Hallo Herr Geigenberger,
Ihr sehr interessantes Konzept ist eines zur DATENSPIEGELUNG, nicht zur DatenSICHERUNG (sofern man unter "Sicherung" wie bei TurboMed intern versteht, daß diese auch überprüft ist).
Irgendwie ist es schon eine Datensicherung, da die Dateien ja 2 Wochen auf dem Rechner bleiben (und durch die Spiegelung die Daten ja auch _gesichert_ sind). Eine eigentliche 'Datensicherung' mittels der TurboMed-eigenen Routine wird aber trotzdem von mir immer noch gemacht.
wahnfried hat geschrieben: 2) Es wird allgemein abgeraten TurboMed auf der Systempartition zu installieren. Sollte ein Systemcrash erfolgen, der die Systempartition unbrauchbar macht, ist es meist möglich, auf weitere Partitionen zuzugreifen, wenn man die Festplatte in einen anderen PC als zweite Festplatte einbaut, nicht unbedingt (eher gar nicht?) aber auf Ordner der Systempartition. Das wäre der Unterschied zwischen den Praxisdaten zum Zeitpunkt der letzten Sicherungsroutine bis zum Zeitpunkt des Systemcrashes, der dann nach dem Serverwechsel verloren wäre, bei TurboMed auf "Nicht-C" aber rekonstruierbar wäre (egal, ob man die Daten seit dem Serverwechselauf der Platte des Ersatzservers per Hausbesuchsmodul der Datenbank auf der Crash-Server-Festplatte implementiert oder die Daten der gecrashten Platte seit der letzten Sicherung (deren Zeit Sie ja dokumentieren) auf der Platte des ERstzservers implementiert.
Ich rechne sogar mit einem Systemcrash, mit einem völlig unbrauchbaren Computer (Hauptserver) und evtl. auch einer unbrauchbaren Festplatte! Deshalb geschieht die Spiegelung ja auf einen ganz anderen Rechner! Dieser ist dann als Server sofort einsatzbereit!! Denn selbst nur eine einzige Stunde ohne EDV an einem Montag-Morgen (Landarzt-Praxis) wäre das Chaos!!
wahnfried hat geschrieben: Diese Nacharbeit wäre danan ja am Abend nach dem Crash-Tag dran, um diese Lücke zu rekonstruieren. Kann ja auch sein, daß die Festplatte des Crash-Servers NICHT DEFEKT ist, sondern Mainboard/Grafikkarte/Hauptspeicher uws. (insofern auch über Einbau der Serverfestplatte in einen Wechsel-Einschub überlegen, um diese sehr rasch in einem zweiten Rechner testen zu können.
Nacharbeiten sind kaum nötig - meinen Athlon Rechner werfe ich im Crashfall schlicht weg :-) - natürlich erst, nachdem ich Dateninkongruenzen beseitigt habe, die deshalb vorhanden sein könnnen, weil es eine Zeitlücke gibt seit der letzten Datenspiegelung mit der 'Inbetriebnahme' des Zweitservers. Die Kosten sind zu verschmerzen (ungefähr in Höhe einer Zigarettenpause eines EDV-Fachmannes):

Mainboard: http://www.mix-computer.de/html/product ... eId=345524 (Vorteil: Grafik onboard reicht für's Büro, Grafikkarte nicht nötig)
CPU: http://www.mix-computer.de/html/product ... eId=209897 (Vorteil: sehr Strom-sparend (35 Watt) und leistungsmäßig meiner aktuellen Hardware deutlich überlegen - obwohl ich mit dem aktuellen PC - wie gesagt - zufrieden bin)

Gehäuse, Netzteil und evtl. Arbeitsspeicher nehme ich von einem anderen (alten) Computer -> Preis ca. 80,- Euro für einen neuen Rechner!!! Ich statte übrigens derzeit alle meine Praxisrechner mit dieser 'überragenden' identischen(!) Hardware aus, so dass ich jederzeit die Systemplatte eines Rechners in jeden anderen Rechner ummontieren kann.
wahnfried hat geschrieben: Bemerkung zum Thema "Kontrolle der ablaufenden Aktion":
Ich möchte auch am Ende einer Spiegelung sehen, daß die Datenbanken korrekt beendet wurde ...
Die Datenspiegelung läuft zeitgesteuert im Hintergrund und wird von niemanden beachtet.

Auf Ihre 'Testergebnisse' bin ich aber nun schon gespannt und freue mich über jeden Verbesserungsvorschlag.

Viele Grüße

A. Geigenberger
JR
PowerUser
Beiträge: 400
Registriert: Donnerstag 26. Mai 2005, 10:48
18

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von JR »

Lieber Herr Geigenberger,

es ist interessant, dass Ihr Server mit relativ bescheidener Hardware schnell läuft. Mich würde interessieren, ob sie auf Ihrem Praxissystem auch das serverbasierte PraxisCenter von IFAP laufen haben, da ich dann tatsächlich die Anschaffung neuer Festplatten in Erwägung ziehen würde? Nach meiner Beobachtung ist es nämlich so, dass das Netzwerk hauptsächlich durch IFAP, nicht durch TurboMed selbst, verlangsamt wird. Leider ist bei Benutzung von IFox der sinnvolle Einsatz einer Client-Installation von IFAP aber nicht möglich (wegen der Notwendigkeit der Abrechnung der Clicks).
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo JR,

Ifap ist auf jedem Rechner lokal installiert und läuft nicht über's Netz. Verwenden tu ich aber die (ebenfalls jeweils lokal installierte) Gelbe Liste, die m.E. viieel besser ist. Die Medikamenten-Statistik interssiert mich nicht - ich hatte da bisher keine Probleme mit der KV.
Und deshalb habe ich mich auch noch nie für IFOX interessiert; ehrlich gesagt weiß ich nichtmal, was das ist :oops: Was ist eigentlich die Abrechnung der 'Clicks' ?

Viele Grüße
A. Geigenberger
JR
PowerUser
Beiträge: 400
Registriert: Donnerstag 26. Mai 2005, 10:48
18

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von JR »

IFox brauche ich hier zum Überprüfen der Wechselwirkungen, weil die verordneten Medikamente aus dem neurologischen und psychiatrischen Fachbereich viele Interaktionen haben können. Ich habe ein bestimmtes Guthaben an Abfragen bei IFAP bezahlt, der Preis ist nicht hoch. Damit man von allen Stationen aus an die Interaktionen herankommt, muss man das Praxiscenter auf dem Server installieren.
buschgespenst
Beiträge: 41
Registriert: Donnerstag 11. Juni 2009, 21:44
14

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von buschgespenst »

Mein Turbomed Systembetreuer hat mich darauf hingewiesen, dass eine sichere Datensicherung nur erfolgen könne, wenn der FastObjectServer vorher abgeschaltet wird. Könnt Ihr dies bestätigen. Dann muss ich nämlich meine Datensicherungsstratgie überdenken.
Benutzeravatar
wahnfried
PowerUser
Beiträge: 3180
Registriert: Freitag 13. Januar 2006, 23:46
18
Wohnort: Braunschweig

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von wahnfried »

buschgespenst hat geschrieben:Mein Turbomed Systembetreuer hat mich darauf hingewiesen, dass eine sichere Datensicherung nur erfolgen könne, wenn der FastObjectServer vorher abgeschaltet wird. Könnt Ihr dies bestätigen. Dann muss ich nämlich meine Datensicherungsstratgie überdenken.
...damit meint er wohl, daß die Datenbanken per TMAdmin in den Backupmodus versetzt werden müssen, wie auch in dem von Herrn Geigenberger angegebenen Konfigurationsbeispiel oder im Bereich "Datenspiegelung im Betrieb" des Wiki (bzw. in den dort downloadbaren scripts) implementiert.

Sollte er wirklich meinen, daß der FastObjectsServer für eine Datensicherung abgeschaltet werden müßte, sollten Sie ihn mal zur Nachschulung nach Molfsee beordern lassen (oder ihn einfach dazu verpflichten, dieses Forum regelmäßig zu lesen). Wenn dem so wäre, könnte eine TurboMed-interne DaSi ja keinesfalls am Server laufen, da dort der FOS seit dem Betriebssystem-Start bis zum Herunterfahren pausenlos läuft (Ausnahme: während eines Updates). Und jegliche TurboMed-interne DaSi von einem Client-Rechner aus durchgeführt KANN nur auf die Server-Datenbank zugreifen, WEIL der FOS läuft.

Grüsse, Wahnfried
buschgespenst
Beiträge: 41
Registriert: Donnerstag 11. Juni 2009, 21:44
14

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von buschgespenst »

Ich habe bezüglich des FOS nochmals explizit nachgefragt bei meinem Systembetreuer nachgefragt. Laut Empfehlung von TM aus Molfsee sollte der FOS während der Datensicherung z.B. mit Acronis beendet werden, um eine vollständige DaSi zu gewährleisten. Das heißt nicht, dass die DaSi mit laufendem FOS nicht auch vollständig sei, jedoch kann es nicht garantiert werden.
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo,

wenn sie mit Acronis sichern, sollten Sie den Server (nur das Programm) wahrscheinlich wirklich abschalten.
Damit: T:\Programm\TMAdmin /beginBackup /server=Bach (ist nur ein Beispiel)
und dann damit: T:\Programm\TMAdmin /endbackup /server=Bach
können Sie das Serverprogramm weiter laufen lassen und auch in der Praxis weiterarbeiten (allerdings etwas langsamer)

A. Geigenberger
buschgespenst
Beiträge: 41
Registriert: Donnerstag 11. Juni 2009, 21:44
14

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von buschgespenst »

Danke für die Antwort. D.h., ich erstelle zwei bat.-Dateien mit jeweils einer Befehlszeile und starte die entsprechende vor und nach DaSi? (passe natürlich den Pfad noch an) Dann ist es nicht nötig, dass ich den FOS als Prozess mit dem taskkill Befehl beende?
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Ja, genau. Sie können diese Befehle aber auch in eine einzige Bat-Datei schreiben.
Dazwischen müssen Sie aber noch einige Befehlszeilen in die Bat-Datei einfügen, damit die Datensicherung überhaupt erst läuft. Sonst würden Sie ja nur den Datensicherungsmechanismus ein und dann gleich wieder ausschalten. (Oder Sie starten zwischen diesen beiden Befehlen die Datensicherung manuell, aber warum?)

A. Geigenberger

(Seit einiger Zeit arbeite ich mit Robocopy - nach Empfehlung von Wahnfried :-) - das geht deutlich schneller; meine aktuelle Batch-Datei poste ich hier in Kürze)
FranzKonrad
Beiträge: 516
Registriert: Dienstag 7. Oktober 2008, 13:56
15
Wohnort: 91463 Dietersheim

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von FranzKonrad »

Geigenberger hat geschrieben:...wenn sie mit Acronis sichern, sollten Sie den Server (nur das Programm) wahrscheinlich wirklich abschalten.
Damit: T:\Programm\TMAdmin /beginBackup /server=Bach (ist nur ein Beispiel)
und dann damit: T:\Programm\TMAdmin /endbackup /server=Bach
können Sie das Serverprogramm weiter laufen lassen und auch in der Praxis weiterarbeiten (allerdings etwas langsamer) ...
Hallo,

hatte denn schon jemand den Ernstfall gehabt, daß er eine Datensicherung, die unter mit TMAdmin aktiviertem Backupmodus erfolgt ist, zurückspielen mußte? Gab es dabei keine Probleme?
Mir fällt auf daß sich (mit Windows Sicherungsprogramm, bzw. auch mit xcopy):
- im normalen Modus (und bei überall beendetem Turbomed) alle Dateien sichen lassen,
- im Backupmodus dagegen genau 4 Dateien nicht gesichert werden, da sie gesperrt sind, egal ob TM läuft oder nicht.
(\Turbomed\PraxisDB\Backup\eventlog\f0000000.ptd,\Turbomed\PraxisDB\Backup\recovery\data0000.rcy,
\Turbomed\PraxisDB\eventlog\f0000000.ptd,\Turbomed\PraxisDB\recovery\data0000.rcy)
Diese Dateien werden offenbar für den Weiterbetrieb von Turbomed im Backupmodus benötigt, werden aber durch den Backupmodus auch dann gesperrt, wenn Turbomed nicht läuft.
Mit einem Festplattenimagebackup werden diese Dateien dann zwar mitgesichert, es fehlt dann aber höchstwahrscheinlich die Konsistenz.
Ich mußte einmal eine Rücksicherung vornehmen, bekam Turbomed danach aber erst mit einigen Tricks wieder zum laufen (weiß nicht mehr genau, wie ichs dann geschafft habe, glaube, ich habe einige, evtl. die o.g. 4 Dateien aus der Datenbank löschen müssen, die dann von TM neu angelegt wurden).
Das hat mich etwas verunsichert, daher sichere ich jetzt nur noch ohne diesen Backupmodus bei beendetem Turbomed. Damit klappte das Rücksichern problemlos und ohne erkennbare Fehler.

Gruß

FranzKonrad
Benutzeravatar
wahnfried
PowerUser
Beiträge: 3180
Registriert: Freitag 13. Januar 2006, 23:46
18
Wohnort: Braunschweig

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von wahnfried »

FranzKonrad hat geschrieben:...eine Datensicherung, die unter mit TMAdmin aktiviertem Backupmodus erfolgt ist, zurückspielen mußte? Gab es dabei keine Probleme?
Mir fällt auf daß sich (mit Windows Sicherungsprogramm, bzw. auch mit xcopy):
- im normalen Modus (und bei überall beendetem Turbomed) alle Dateien sichen lassen,
- im Backupmodus dagegen genau 4 Dateien nicht gesichert werden, da sie gesperrt sind, egal ob TM läuft oder nicht.
(\Turbomed\PraxisDB\Backup\eventlog\f0000000.ptd,\Turbomed\PraxisDB\Backup\recovery\data0000.rcy,
\Turbomed\PraxisDB\eventlog\f0000000.ptd,\Turbomed\PraxisDB\recovery\data0000.rcy)
Diese Dateien werden offenbar für den Weiterbetrieb von Turbomed im Backupmodus benötigt, werden aber durch den Backupmodus auch dann gesperrt, wenn Turbomed nicht läuft.
Hallo,

hat sich da etwas verändert?

TurboMed 10.2.0.1711 :
Die "Datenspiegelung im Betrieb" kopiert die o.a. Dateien nach Batch-Protokoll mit (kopiert also für die PraxisDB 8 Dateien und für die DruckDB 4 Dateien), das Umstellen auf Einzelplatzarbeit funktioniert problemlos mit vollem Datenbestand - das wäre m.E. einer Rücksicherung auf den Server gleichbedeutend. Die Dateigrößen auf Server und Spiegel-Client sind nach der "Datenspiegelung im Betrieb" identisch.

TurboMed 10.3.1.1770 :
unverändert wie für 10.2.0.1711 angegeben. Einzelplatzmodus weiterhin nach Spiegelung der Datenbanken sofort lauffähig. Nach Umbenennen der PraxisDB am Server und Kopieren der vom per TMAdmin gespiegeltem Client auf den Server: sofort lauffähiges TurboMed am Server...

TurboMed 10.4.1 noch nicht in der Praxis installiert, nur Einzelplatz... :oops:
Umbau zum Server habe ich allerdings zuletzt 10/2009 für mich selbst gemacht, allerdings 9/2010 für eine andere Praxis mit TurboMed 10.3.1.1770...

Grüsse, Wahnfried
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo,

ich bin sicher kein Datenbankspezialist. Aber könnte es sein, dass diese gesperrten und nicht mitgesicherten 4 Dateien genau die Dateien sind, die der Fast-ObjektServer (=Poet-Server) anlegt WÄHREND er sich im Backupmodus befindet. Denn irgenwo müssen die Daten ja zwischengespeichert werden, während das Backup läuft.

Wie ich beschrieben habe, habe ich ja einen einfachen Arbeitsplatzrechner als 'Notfallserver' konfiguriert. Wenn ich diesen 'Notfallserver' nach so einer Datensicherung alleine als Server hochfahre, dann habe ich bisher noch nie Dateninkonsistenzen festgestellt.

A. Geigenberger
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Jetzt aber nochmal zur 'aktualisierten' Version meiner Batch-Sicherungs-Datei. Nun verwende ich statt Xcopy Robocopy. Außerdem werden durch den ECHO-Befehl nun Log-Dateien angelegt (und mit abgespeichert - und am Ende angezeigt) und nicht mehr am Bildschirm ausgegeben.

<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

@echo off
@cls
@echo off

FOR /F "tokens=1,2,3 delims=." %%a in ('echo %date%') do set yy=%%c & set mm=%%b & set dd=%%a

set /a "TwoDigitYearMax=2038%%1000"
if 1%yy% LSS 200 if 1%yy% LSS 1%TwoDigitYearMax% (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1

If %dow% equ 1 set "WoTa=Montag"
If %dow% equ 2 set "WoTa=Dienstag"
If %dow% equ 3 set "WoTa=Mittwoch"
If %dow% equ 4 set "WoTa=Donnerstag"
If %dow% equ 5 set "WoTa=Freitag"
If %dow% equ 6 set "WoTa=Samstag"
If %dow% equ 7 set "WoTa=Sonntag"

echo.
echo.
echo.
echo.
echo.
echo ########## Sicherung wichtiger Praxis-Daten #########
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo.

ping -n 1 x 127.0.0.1 > NUL

echo Erstellt am: %date% um: %time% > C:\tmdaten\log_file_rob.txt
echo Erstellt am: %date% um: %time% > C:\tmdaten\log_file_lev.txt

cls
echo.
echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo ############ Spiegelung der Praxis-Datenbank
echo.
echo.
T:\Programm\TMAdmin /beginBackup /server=Bach
echo.
echo.
echo ############################
robocopy Z:\Dictionary C:\tmdaten\Dictionary /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 01 ## Errorlevel: %ERRORLEVEL% ##
echo ## 01 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy Z:\DruckDB C:\tmdaten\DruckDB /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 02 ## Errorlevel: %ERRORLEVEL% ##
echo ## 02 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy Z:\PraxisDB C:\tmdaten\PraxisDB /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 03 ## Errorlevel: %ERRORLEVEL% ##
echo ## 03 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy T:\IV_Verwaltung\data\Data C:\tmdaten\IV_Verwaltung /MIR /NP /LEV:1 /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 04e ## Errorlevel: %ERRORLEVEL% ##
echo ## 04 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%


T:\Programm\TMAdmin /endbackup /server=Bach


robocopy Z:\Symbole C:\tmdaten\Symbole /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 11 ## Errorlevel: %ERRORLEVEL% ##
echo ## 11 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy Z:\Vorlagen C:\tmdaten\Vorlagen /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 12e ## Errorlevel: %ERRORLEVEL% ##
echo ## 12 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy T:\Desktopobjekte C:\tmdaten\Desktopobjekte /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 21 ## Errorlevel: %ERRORLEVEL% ##
echo ## 21 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\IV_Verwaltung C:\TurboMed\IV_Verwaltung\data\Data /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 22 ## Errorlevel: %ERRORLEVEL% ##
echo ## 22 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\IV_Verwaltung C:\TurboMed\IV_Verwaltung\data\Data /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 23e ## Errorlevel: %ERRORLEVEL% ##
echo ## 23 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\IV_Verwaltung C:\TurboMed\IV_Verwaltung\data\Data /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
rem Dateien werden an zwei Stellen des TM-Dateisystems gelegt (man weiss ja nie :-)
echo.
echo ############################ 31 ## Errorlevel: %ERRORLEVEL% ##
echo ## 31 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\Symbole C:\TurboMed\Symbole /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 32 ## Errorlevel: %ERRORLEVEL% ##
echo ## 32 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\Vorlagen C:\Turbomed\Vorlagen /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 33 ## Errorlevel: %ERRORLEVEL% ##
echo ## 33 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%


robocopy C:\tmdaten\Desktopobjekte C:\TurboMed\Desktopobjekte /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 34e ## Errorlevel: %ERRORLEVEL% ##
echo ## 33 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%


C:\tmdaten\B_%date:~-4%_%date:~-7,2%_%date:~-10,2%_%time:~-0,2%_%time:~3,2%_%time:~6,2%_%time:~9,2%.txt

echo.

set /a aktmonat=%date:~-4%%date:~-7,2%
set /a vormonat=%date:~-4%%date:~-7,2%-1

robocopy Z:\Dokumente\Sonstiges\%vormonat% C:\tmdaten\Dokumente\Sonstiges\%vormonat% /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ########################## 41 ##Errorlevel: %ERRORLEVEL% ##
echo ## 41 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

echo.
robocopy Z:\Dokumente\Sonstiges\%aktmonat% C:\tmdaten\Dokumente\Sonstiges\%aktmonat% /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ########################## 42e ##Errorlevel: %ERRORLEVEL% ##
echo ## 42 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

echo.
echo ########## Heute ist: %WoTa% ,der %date% #######
echo.
echo ############ ....umkopieren
echo.

Rmdir /Q /S C:\tmdaten_sich_wochenweise\%WoTa%\O5
ren C:\tmdaten_sich_wochenweise\%WoTa%\O4 O5
ren C:\tmdaten_sich_wochenweise\%WoTa%\O3 O4
ren C:\tmdaten_sich_wochenweise\%WoTa%\O2 O3
ren C:\tmdaten_sich_wochenweise\%WoTa%\O1 O2
Mkdir C:\tmdaten_sich_wochenweise\%WoTa%\O1


robocopy C:\tmdaten\Dictionary C:\tmdaten_sich_wochenweise\%WoTa%\O1\Dictionary /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 51 ## Errorlevel: %ERRORLEVEL% ##
echo ## 51 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\DruckDB C:\tmdaten_sich_wochenweise\%WoTa%\O1\DruckDB /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 52 ## Errorlevel: %ERRORLEVEL% ##
echo ## 52 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\PraxisDB C:\tmdaten_sich_wochenweise\%WoTa%\O1\PraxisDB /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 53 ## Errorlevel: %ERRORLEVEL% ##
echo ## 53 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\Vorlagen C:\tmdaten_sich_wochenweise\%WoTa%\O1\Vorlagen /MIR /NP /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 54 ## Errorlevel: %ERRORLEVEL% ##
echo ## 54 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

robocopy C:\tmdaten\IV_Verwaltung C:\tmdaten_sich_wochenweise\%WoTa%\O1\IV_Verwaltung /MIR /NP /LEV:1 /LOG+:C:\tmdaten\log_file_rob.txt
echo.
echo ############################ 55e ## Errorlevel: %ERRORLEVEL% ##
echo ## 55 ## Errorlevel: %ERRORLEVEL% ## >> C:\tmdaten\log_file_lev.txt
set /a fehler=%fehler%+%ERRORLEVEL%

rem StammDB sollte bei jedem Update von TurboMed aktualisiert werden (noch kontrollieren!!)

echo Datei Ende: %date% um: %time% >> C:\tmdaten\log_file_rob.txt
echo Datei Ende: %date% um: %time% >> C:\tmdaten\log_file_lev.txt

copy C:\tmdaten\log_file_lev.txt C:\tmdaten_sich_wochenweise\%WoTa%\O1
copy C:\tmdaten\log_file_rob.txt C:\tmdaten_sich_wochenweise\%WoTa%\O1

C:\tmdaten\log_file_lev.txt

REM ################################################
REM ################################################
echo.
echo ####### ENDE ##########
echo ####### ENDE ##########
echo ####### ENDE ##########
ping -n 1 x 127.0.0.1 > NUL
FranzKonrad
Beiträge: 516
Registriert: Dienstag 7. Oktober 2008, 13:56
15
Wohnort: 91463 Dietersheim

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von FranzKonrad »

Hallo,
Wahnfried hat geschrieben:... hat sich da etwas verändert? ...
Nein, sicher nicht, das ist bei mir schon immer so. (s.u.)
Geigenberger hat geschrieben:Hallo,

ich bin sicher kein Datenbankspezialist. Aber könnte es sein, dass diese gesperrten und nicht mitgesicherten 4 Dateien genau die Dateien sind, die der Fast-ObjektServer (=Poet-Server) anlegt WÄHREND er sich im Backupmodus befindet. Denn irgenwo müssen die Daten ja zwischengespeichert werden, während das Backup läuft.

Wie ich beschrieben habe, habe ich ja einen einfachen Arbeitsplatzrechner als 'Notfallserver' konfiguriert. Wenn ich diesen 'Notfallserver' nach so einer Datensicherung alleine als Server hochfahre, dann habe ich bisher noch nie Dateninkonsistenzen festgestellt.

A. Geigenberger
nein, diese Dateien sind immer da, aber offenbar legt TMAdmin im Backup-Modus "die Hand drauf".
Nachdem ich scheinbar der einzige bin, der damit Probleme hat, (vielleicht auch als einziger das Windows Sicherungsprogramm nutze? Ich brauchs, da ich damit auf DAT-Bänder sichere) habe ich jetzt etwas nachgelesen und rumprobiert: man kann diese Dateien auch im Backupmodus via Editor ansehen und mittels Maus woanders hinkopieren.
Das Windows-Sicherungsprogramm arbeitet aber mittels Schattenkopie, was ein Verändern der Datei vom Beginn bis zum Ende des Einlesevorganges verhindert.
Dies setzt aber voraus, daß jeglicher anderer Schreibzugriff auf diese Datei für ganz kurze Zeit gesperrt werden muß: Schreibsperre Anfang -> Datei einlesen -> Schreibsperre Ende.
Und da liegt wohl der Haken: Ich arbeite grundsätzlich nicht mit Administratorrechten, sondern schon seit Windows NT als "Hauptbenutzer", was damals für Turbomed ansonsten gut reichte. Offenbar kommt das Windows-Sicherungsprogramm mit meinen Rechten aber nicht gegen den FastObjectServer an und kann diese kurzzeitige Zugriffssperre nicht ausführen: da dann die Datenkonsistenz nicht gewährleistet ist, werden diese Dateien übersprungen.
Die Fehlermeldung im Protokoll ist da schwer verständlich, öffnen ginge ja, aber der Schritt davor mit der Schreibsperre nicht.

So stehts dann im Sicherungsprotokoll:
"Sicherung begonnen am 05.12.2010 um 22:22.
Warnung: "E:\Turbomed\PraxisDB\Backup\eventlog\f0000000.ptd" kann nicht geöffnet werden und wird übersprungen.
Ursache: Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess verwendet wird.

Warnung: "E:\Turbomed\PraxisDB\Backup\recovery\data0000.rcy" kann nicht geöffnet werden und wird übersprungen.
Ursache: Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess verwendet wird.

Warnung: "E:\Turbomed\PraxisDB\eventlog\f0000000.ptd" kann nicht geöffnet werden und wird übersprungen.
Ursache: Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess verwendet wird.

Warnung: "E:\Turbomed\PraxisDB\recovery\data0000.rcy" kann nicht geöffnet werden und wird übersprungen.
Ursache: Der Prozess kann nicht auf die Datei zugreifen, da sie von einem anderen Prozess verwendet wird."


Hab mich jetzt mal versuchsweise als Administrator eingeloggt: da ließen sich auch diese 4 Dateien sichern.
Da ich weiterhin im Routinebetrieb nicht als Administrator arbeiten will, werde ich mal versuchen, die Dateizugriffsrechte anzupassen, oder alternativ evtl. nur das Backupprogramm unter dem Administratorkonto starten.

Gruß, und nix für ungut

FranzKonrad
Benutzeravatar
wahnfried
PowerUser
Beiträge: 3180
Registriert: Freitag 13. Januar 2006, 23:46
18
Wohnort: Braunschweig

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von wahnfried »

Geigenberger hat geschrieben:Jetzt aber nochmal zur 'aktualisierten' Version meiner Batch-Sicherungs-Datei. Nun verwende ich statt Xcopy Robocopy. Außerdem werden durch den ECHO-Befehl nun Log-Dateien angelegt (und mit abgespeichert - und am Ende angezeigt) und nicht mehr am Bildschirm ausgegeben.
Hallo Herr Geigenberger,

die Datensicherung läuft (auch in der xcopy-Variante) von Chopin aus, nicht wahr?

Die LOG-Daten-Abspeicherung ist ein Robocopy-Feature?

Dictionary habe ich noch nie in eine Spiegelung/Speicherung eingebaut, was ist der Sinn dabei?

Wo haben Sie die Wochentags-Berechnung her? (verstanden habe ich sie noch nicht...)

Für den Serverwechsel haben Sie also auf einem dritten Rechner "Verdi" (oder auf jedem Client separat) eine "Local.ini" sowohl für die Kommunikation mit Bach als auch für die mit Chopin mit den veränderten Angaben zum Server fest abgespeichert, die auf jedem Client nach dem Serverwechsel aktiviert werden würde? Das würde bedeuten, daß in der Zwischenzeit erfolgte Veränderungen/Erweiterungen der Lokal.ini nicht mitvollzogen werden. Soweit ich es mitbekommen habe, verwendet TurboMed bei nicht in der Lokal.ini/Global.ini definierten Einstellungen eine Default-Einstellung (sonst wären die Lokal.ini/Global.ini der Demo-Version nicht so klein...). Das bedeutet: falls seit der letzten Aktualisierung der vorbereiteten Serverwechsel-ini's neu hinzugekommene Einstellungen der Lokal.ini praxisbezogen verändert wurden, wäre dies nach dem Serverwechsel perdu (außer es wären die vorbereiteten Lokal.ini's jedesmal mit angepaßt worden...).

Wenn es nun möglich wäre, per script innerhalb der Lokal.ini den Begriff "Bach" gegen "Chopin" (oder umgekehrt) auszutauschen, wäre das die universellere Lösung. Das müßte eigentlich unabhängig davon funktionieren, ob "Bach" und "Chopin" nur beim Servernamen erwähnt werden oder auch in den Verzeichnispfaden. TurboMed kann ja beim Update auch Einfügungen in den Dateien Lokal.ini/Global.ini erzeugen. Insofern dies als Frage an die Script-Künstler...

Sollten bei den Verzeichnispfaden die Netzlaufwerke Verwendung finden, müssten diese dann auch scriptgesteuert ausgetauscht werden gegen alternativ bereits vorbereitete Netzlaufwerke zu Chopin (analog zu T: und Z: zu Bach) - oder in den vorbereiteten .ini's entsprechend ersetzte Angaben. Wer solches nicht möchte, sollte in den Verzeichnis-Pfadangaben keine Netzlaufwerkangaben verwenden, da diese nach dem Serverwechsel ja nicht mehr funktionieren (außer, man würde sie auf jedem Client trennen und neu zu Chopin verbinden = Handarbeit). Die Begriffe "Bach" und "Chopin" dürfen da aber gerne stehen. Oder die weiter unten vorgeschlagenen "anderen" Netzlaufwerke von Verdi nach Chopin werden eben auch auf allen anderen Client-Rechnern bereits vorbereitet und können dann entsprechend dem Ziel-Server der jeweiligen Lokal.ini verwendet werden.

Alternativ wäre auch ein Abspeichern der bisher benutzten Lokal.ini analog zu dem Verfahren in meiner Moduswechsel-Batch möglich, dann hätte man wenigstens beim Zurückwechseln auf "Bachs Sohn" wieder die individuellen Einstellungen auf jeden Fall wiederhergestellt (und könnte sogar durch geänderte Hintergrundfarben auf den anderen Server hinweisen).

Für den Fall des Serverwechsels müßte dann das Datensicherungsscript noch transplantiert und überarbeitet werden (kopieren nach Verdi, dort im script Chopin ersetzen durch Verdi, dann Bach ersetzen durch Chopin, ggfs. auch bereits vorbereitete abweichend benannte Netzlaufwerksverbindungen von Verdi nach Chopin einrichten und statt "T:" und "Z:" verwenden), damit nach Bachs Ableben die tägliche Sicherung weiter geht... - dann nach einem Serverwechsel: Script auf Verdi aktivieren / Ursprungsscript auf Chopin deaktivieren (und ggfs. umgekehrt), z.B. jeweils durch "rename" der Batch - das wäre scriptgesteuert möglich - oder durch Aktivieren/Deaktivieren des geplanten Tasks - das könnte Handarbeit erfordern.

Eine schriftliche Beschreibung der notwendigen Schritte beim Serverwechsel haben Sie im Sinne von QM sicher parat...

Viele Grüsse, Wahnfried
Benutzeravatar
Geigenberger
PowerUser
Beiträge: 1302
Registriert: Dienstag 9. Dezember 2003, 22:26
20
Bedankt: 3 times

Re: Datensicherung - Konfigurationsbeispiel

Beitrag von Geigenberger »

Hallo Herr Wahnfried,
wahnfried hat geschrieben: Hallo Herr Geigenberger,
die Datensicherung läuft (auch in der xcopy-Variante) von Chopin aus, nicht wahr?
ja; Chopin ist der 'Ersatz-Server und ein beliebiger Arbeitsplatzrechner.
wahnfried hat geschrieben: Die LOG-Daten-Abspeicherung ist ein Robocopy-Feature?
ja
wahnfried hat geschrieben: Dictionary habe ich noch nie in eine Spiegelung/Speicherung eingebaut, was ist der Sinn dabei?
"schadet nicht" braucht minimal Zeit und Platz
wahnfried hat geschrieben: Wo haben Sie die Wochentags-Berechnung her? (verstanden habe ich sie noch nicht...)
im Internet gefunden. Schön, nicht wahr? Funktioniert super; verstehen tu ich das auch nicht :mrgreen:
wahnfried hat geschrieben: Für den Serverwechsel ...........
Ein Serverwechsel war bisher zum Glück nur zu Testzwecken nötig. Dazu habe ich eine angepasste local.ini-Datei auf jedem Rechner des Netzwerkes, die einfach nur ausgetauscht wird; mittlerweile auch mittels eines einfachen (separaten!) Scripts. Dieses Script muß aber nicht in die täglich zweimal laufende Kopierroutine eingebunden werden, da die akute Notwendigkeit zum Serverwechsel ja höchst selten (hoffentlich nie) besteht.
Der Laufwerkbuchstabe "Z" ist gemappt auf das 'Datenverzeichnis' tmdaten des Servers 'Bach'.
wahnfried hat geschrieben: Eine schriftliche Beschreibung der notwendigen Schritte beim Serverwechsel haben Sie im Sinne von QM sicher parat...
Aber klar!! 8) :roll:

Viele Grüße!
A. Geigenberger
Antworten

Wer ist online?

Mitglieder in diesem Forum: Ahrefs [Bot] und 64 Gäste